//
// [==================================================]
// [===========      Warper Evolution      ===========]
// [==================================================]
// [ Versión 18                                       ]
// [==================================================]
// [ Script original: Ivion                           ]
// [==================================================]
// [ Descripción:                                     ]
// [--------------------------------------------------]
// [                                                  ]
// [ - Save.                                          ]
// [ - Warp a Ciudades.                               ]
// [ - Warp a Mazmorras.                              ]
// [ - Warp a Áreas de WoE.                           ]
// [ - Warp a otros Grupos de Destinos personalizados.]
// [ - Totalmente configurable.                       ]
// [ - Modo Evolution / Quest Warper.                 ]
// [==================================================]
// [ 5 últimas actualizaciones:                       ]
// [--------------------------------------------------]
// [                                                  ]
// [ v14: [Ivion]                                     ]
// [ - Algunos cambios en la configuración.           ]
// [ - Añadida configuración para Grupos de Destinos. ]
// [ - Remodelado el funcionamiento del script.       ]
// [ - Cambiadas algunas posiciones de npcs y warps.  ]
// [                                                  ]
// [ v15: [Ivion]                                     ]
// [ - Simplificado el sistema de configuración.      ]
// [ - Bajados los precios por defecto.               ]
// [ - Variables por Bitwise.                         ]
// [                                                  ]
// [ v16: [Ivion]                                     ]
// [ - Los duplicados sólo ejecutan los diálogos.     ]
// [ - Añadido Midgarts Expedition Camp.              ]
// [ - Conf para cambiar el nombre de todos los NPCs. ]
// [                                                  ]
// [ v17: [Ivion]                                     ]
// [ - Bugfix: Los npc muestran los emotion.          ]
// [ - Variables de npc sustituidas por globales.     ]
// [                                                  ]
// [ v18: [Ivion]                                     ]
// [ - El Id de cada destino no dependerá de su Grupo.]
// [ - Bugfix: Coordenadas de Payon.                  ]
// [ - Nueva declaración de submenús.                 ]
// [ - Traducciones oficiales de los destinos.        ]
// [ - Geffenia ahora es parte de Geffen Dungeon.     ]
// [ - BugFix: Algunos índices de los npcs.           ]
// [ - BugFix: Labyrinth Forest, Mjolnir Dead Pit,    ]
// [    Moscovia Forest.                              ]
// [ - Todos los niveles de las dungeons activan los  ]
// [    destinos.                                     ]
// [ - Añadida Beach Dungeon.                         ]
// [==================================================]

-	script	WEfunc	-1,{

OnInit:

// [==================================================]
// [ Configuración:                                   ]
// [--------------------------------------------------]

	// Nombre del NPC:
	set .@n$,"Warper Evolution";

	// Guardar Punto de Inicio:
	// callsub Onc0,{"Nombre"}{,Precio};

	callsub Onc0,"Guardar Punto de Inicio.",0;

// [--------------------------------------------------]
// [ Final de la configuración.                       ]
// [==================================================]

// [==================================================]
// [ Configuración de Destinos:                       ]
// [--------------------------------------------------]

	// Declaración de Grupos de Destinos:
	// callsub Onc0,{"Nombre"}{,Precio};
	// Crea una nueva entrada dentro del menú principal del npc.
	// Para más de 20 Grupos de Destinos, ver (Nota 1).

	// Declaración de Destinos:
	// callsub Onc1,{Id},{"Nombre"},{"Mapa"},{x},{y}{,"Mapa Activación 1"}{,"Mapa Activación 2"}{,...};
	// Crea un nuevo Destino dentro del último Grupo de Destinos declarado anteriormente.
	// {Id}: Identificador único del destino. Ponedlo a 0 si queréis desactivar el Modo Evolution.
	// {"Mapa Activación #"}: En los destinos en Modo Evolution, cuando el jugador se sitúe sobre cualquiera de estos mapas,
	//   el destino quedará desbloqueado, permitiendo al jugador viajar hasta él a través del Warper.
	//   Puedes añadir todos los mapas de activación que desees en los sucesivos argumentos de la declaración.
	// Para más de 50 Destinos en cada Grupo de Destinos, ver (Nota 2).

	// Declaración de Submenús:
	// callsub Onc2,{"Nombre"};
	// Crea un Submenú dentro del último Grupo de Destinos declarado anteriormente.
	// Es útil para agrupar diferentes Destinos, por ejemplo para los niveles de Dungeon.
	// Para cerrar un submenú, debeis utilizar la misma función sin argumentos.
	// callsub Onc2;

	// Cities:
	callsub Onc0,"Viajar a una Ciudad.",500;
		callsub Onc1,0,"Alberta","alberta",51,241;
		callsub Onc1,1,"Al De Baran","aldebaran",139,121,"aldebaran";
		callsub Onc1,2,"Amatsu","amatsu",93,254,"amatsu";
		callsub Onc1,3,"Ayothaya","ayothaya",207,206,"ayothaya";
		callsub Onc1,4,"Comodo","comodo",202,113,"comodo";
		callsub Onc1,5,"Einbech","einbech",70,90,"einbech";
		callsub Onc1,6,"Einbroch","einbroch",69,196,"einbroch";
		callsub Onc1,0,"Geffen","geffen",117,70;
		callsub Onc1,7,"Gonryun","gonryun",161,119,"gonryun";
		callsub Onc1,8,"Hugel","hugel",96,127,"hugel";
		callsub Onc1,0,"Izlude","izlude",128,92;
		callsub Onc1,9,"Juno","yuno",158,84,"yuno";
		callsub Onc1,10,"Lighthalzen","lighthalzen",214,93,"lighthalzen";
		callsub Onc1,11,"Louyang","louyang",217,114,"louyang";
		callsub Onc1,12,"Lutie","xmas",148,116,"xmas";
		callsub Onc1,13,"Midgarts Expedition Camp","mid_camp",210,288,"mid_camp";
		callsub Onc1,0,"Morroc","morocc",161,71;
		callsub Onc1,14,"Moscovia","moscovia",224,192,"moscovia";
		callsub Onc1,15,"Niflheim","niflheim",194,185,"niflheim";
		callsub Onc1,0,"Payon","payon",158,57;
		callsub Onc1,0,"Prontera","prontera",156,161;
		callsub Onc1,16,"Rachel","rachel",142,139,"rachel";
		callsub Onc1,17,"Umbala","umbala",122,135,"umbala";
		callsub Onc1,18,"Veins","veins",198,232,"veins";

	// Dungeons:
	callsub Onc0,"Viajar a una Mazmorra.",2000;
		callsub Onc1,31,"Abyss Lake Underground Cave","hu_fild05",192,206,"abyss_01","abyss_02","abyss_03";
		callsub Onc1,32,"Amatsu Dungeon","ama_dun01",230,11,"ama_dun01","ama_dun02";
		callsub Onc1,33,"Ant Hell","moc_fild04",205,326,"anthell01","anthell02";
		callsub Onc1,34,"Ayothaya Ancient Shrine","ayo_fild02",277,150,"ayo_dun01","ayo_dun02";
		callsub Onc2,"Beach Dungeon";
			callsub Onc1,64,"Karu, the West Cave","comodo",35,215,"beach_dun";
			callsub Onc1,65,"Ruande, the North Cave","comodo",176,333,"beach_dun2";
			callsub Onc1,66,"Mao, the East Cave","comodo",318,176,"beach_dun3";
		callsub Onc2;
		callsub Onc1,35,"Clock Tower","aldebaran",139,121,"alde_dun03","alde_dun02","alde_dun03","alde_dun04","c_tower1","c_tower2","c_tower3","c_tower4";
		callsub Onc1,36,"Cursed Abbey Dungeon","nameless_n",164,184,"abbey01","abbey02","abbey03";
		callsub Onc1,37,"Geffen Dungeon","gef_dun00",104,97,"gef_dun00","gef_dun01","gef_dun02","gefenia01","gefenia02","gefenia03","gefenia04";
		callsub Onc1,38,"Glast Heim","glast_01",199,114,"glast_01","gl_cas01","gl_cas02","gl_chyard","gl_sew01","gl_sew02","gl_sew03","gl_sew04","gl_church","gl_step","gl_prison","gl_prison1","gl_knt01","gl_knt02","gl_dun01","gl_dun02";
		callsub Onc1,39,"Gonryun Ancient Shrine","gonryun",164,189,"gon_dun01","gon_dun02","gon_dun03";
		callsub Onc1,40,"Holy Ground","ra_temple",120,174,"ra_san01","ra_san02","ra_san03","ra_san04","ra_san05";
		callsub Onc1,41,"Ice Cave","ra_fild01",234,328,"ice_dun01","ice_dun02","ice_dun03","ice_dun04";
		callsub Onc1,42,"Labyrinth Forest","prt_fild01",137,364,"prt_maze01","prt_maze02","prt_maze03";
		callsub Onc1,43,"Mine Dungeon","einbech",135,245,"ein_dun01","ein_dun02";
		callsub Onc1,44,"Mjolnir Dead Pit","mjolnir_02",80,358,"mjo_dun01","mjo_dun02","mjo_dun03";
		callsub Onc1,45,"Moscovia Forest","mosk_fild02",191,252,"mosk_dun01","mosk_dun02","mosk_dun03";
		callsub Onc1,46,"Nogg Road","yuno_fild03",38,139,"mag_dun01","mag_dun02";
		callsub Onc1,47,"Odin Shrine","odin_tem01",111,145,"odin_tem01","odin_tem02","odin_tem03";
		callsub Onc1,48,"Orc Dungeon","gef_fild10",67,332,"orcsdun01","orcsdun02";
		callsub Onc1,49,"Payon Cave","pay_arche",40,130,"pay_dun00","pay_dun01","pay_dun02","pay_dun03","pay_dun04";
		callsub Onc1,50,"Prontera Culvert","prt_fild05",269,204,"prt_sewb1","prt_sewb2","prt_sewb3","prt_sewb4";
		callsub Onc1,51,"Pyramid","moc_ruins",58,154,"moc_pryd01","moc_pryd02","moc_pryd03","moc_pryd04","moc_pryd05","moc_pryd06";
		callsub Onc1,52,"Robot Factory","yuno_fild08",73,179,"kh_dun01","kh_dun02";
		callsub Onc1,53,"Royal Tomb","louyang",47,271,"lou_dun01","lou_dun02","lou_dun03";
		callsub Onc1,54,"Ruins of Juperos","jupe_cave",50,51,"juperos_01","juperos_02","jupe_core";
		callsub Onc1,55,"Somatology Laboratory","lighthalzen",38,299,"lhz_dun01","lhz_dun02","lhz_dun03";
		callsub Onc1,56,"Sphinx","moc_fild19",107,98,"in_sphinx1","in_sphinx2","in_sphinx3","in_sphinx4","in_sphinx5";
		callsub Onc1,57,"Sunken Ship","alb2trea",82,100,"treasure01","treasure02";
		callsub Onc1,58,"Thanatos Tower","tha_scene01",140,199,"tha_t01","tha_t02","tha_t03","tha_t04","tha_t05","tha_t06","tha_t07","tha_t08","tha_t09","tha_t10","tha_t11","tha_t12";
		callsub Onc1,59,"Thor Volcano Dungeon","ve_fild03",169,236,"thor_v01","thor_v02","thor_v03";
		callsub Onc1,60,"Toy Factory","xmas",143,305,"xmas_dun01","xmas_dun02";
		callsub Onc1,61,"Turtle Island","tur_dun01",151,51,"tur_dun01","tur_dun02","tur_dun03","tur_dun04";
		callsub Onc1,62,"Umbala Dungeon","umbala",160,250,"um_dun01","um_dun02";
		callsub Onc1,63,"Undersea Tunnel","izlu2dun",107,93,"iz_dun00","iz_dun01","iz_dun02","iz_dun03","iz_dun04";

	// WoE Areas:
	callsub Onc0,"Viajar a un Área de WoE.",2000;
		callsub Onc1,0,"Britoniah","gef_fild13",191,227;
		callsub Onc1,0,"Greenwood Lake","pay_gld",196,165;
		callsub Onc1,0,"Luina","alde_gld",228,151;
		callsub Onc1,0,"Nidhoggur","sch_gld",288,121;
		callsub Onc1,0,"Valfreyja","aru_gld",186,327;
		callsub Onc1,0,"Valkyrie Realm","prt_gld",160,75;

	// Variables libres: [19,30] U [67,90] U [193,...)

// [--------------------------------------------------]
// [ Final de la configuración de Destinos.           ]
// [==================================================]

	set $@WE,0;
	cleararray $@WEc[0],0,getarraysize($@WEc[0]);
	// Nombre de los NPCs:
	set .@a,1;
	while(!setnpcdisplay("WE#"+.@a,.@n$+"#"+.@a)) set .@a,.@a + 1;
	set $@WE$,"^008888"+.@n$+"^000000";
	end;

// Declaración del menú principal:
Onc0:
	set $@WE,$@WE + 1;
	set getd("$@WE_1_"+$@WE),-1;
	set getd("$@WE_2_"+$@WE+"$"),getarg(0);	// Name.
	set getd("$@WE_3_"+$@WE),getarg(1);	// Price.
	set .@a,getarraysize($@WEm);
	set $@WEm[.@a],$@WE;
	cleararray $@WEc[0],0,getarraysize($@WEc[0]);
	set $@WEc[0],$@WE;
	return;

// Declaración de Destinos:
Onc1:
	set $@WE,$@WE + 1;
	set getd("$@WE_1_"+$@WE),getarg(0);	// Id.
	set getd("$@WE_2_"+$@WE+"$"),getarg(1);	// Name.
	set getd("$@WE_3_"+$@WE+"$"),getarg(2);	// Map.
	set getd("$@WE_4_"+$@WE),getarg(3);	// X.
	set getd("$@WE_5_"+$@WE),getarg(4);	// Y.
	if(getarg(0)) {
		set .@a,5;
		while(getarg(.@a,"") != "") {
			set .@m$,getarg(.@a);
			setmapflag .@m$,42;
			set getd("$@WE_"+.@m$+"["+getarraysize(getd("$@WE_"+.@m$))+"]"),$@WE;
			set .@a,.@a + 1;
		}
	}
	set .@a,$@WEc[getarraysize($@WEc) - 1];
	set .@b,getarraysize(getd("$@WE_4_"+.@a));
	set getd("$@WE_4_"+.@a+"["+.@b+"]"),$@WE;
	return;

// Declaración de Submenús:
Onc2:
	set .@a,getarraysize($@WEc) - 1;
	if((getarg(0,"") == "") && .@a) set $@WEc[.@a],0;
	else {
		set $@WE,$@WE + 1;
		set getd("$@WE_1_"+$@WE),-1;
		set getd("$@WE_2_"+$@WE+"$"),getarg(0);	// Name.
		set .@b,$@WEc[.@a];
		set .@c,getarraysize(getd("$@WE_4_"+.@b));
		set getd("$@WE_4_"+.@b+"["+.@c+"]"),$@WE;
		set $@WEc[.@a + 1],$@WE;
	}
	return;

// Activación de Destinos:
OnPCLoadMapEvent:
	getmapxy .@m$,.@x,.@y,0;
	while(.@a < getarraysize(getd("$@WE_"+.@m$))) {
		set .@b,getd("$@WE_"+.@m$+"["+.@a+"]");
		set .@c,getd("$@WE_1_"+.@b);
		set .@d,getd("WE_"+(.@c / 31));
		if(!(.@d & pow(2,.@c % 31))) {
			announce "Nuevo destino desactivado: "+getd("$@WE_2_"+.@b+"$")+".",bc_self,0x00ccdd;
			set getd("WE_"+(.@c / 31)),.@d + pow(2,.@c % 31);
		}
		set .@a,.@a + 1;
	}
	end;
}

// Npcs:
-	script	WE#0::WE	-1,{

	mes $@WE$;
	mes "Hola "+strcharinfo(0)+".";
	mes "¿En que te puedo ayudar?";
	next;
	while(.@a < getarraysize($@WEm)) {
		set .@b,$@WEm[.@a];
		set .@a$[.@a],getd("$@WE_2_"+.@b+"$");	// Name.
		set .@b,getd("$@WE_3_"+.@b);	// Price.
		if(.@b) {
			if(Zeny < .@b) set .@a$[.@a],"^bbbbbb"+.@a$[.@a]+" ^bb0000("+.@b+" z)^000000";
			else set .@a$[.@a],.@a$[.@a]+" ^00bb00("+.@b+" z)^000000";
		}
		set .@a,.@a + 1;
	}
	set .@a,select("^880000Salir^000000",.@a$[0],.@a$[1],.@a$[2],.@a$[3],.@a$[4],.@a$[5],.@a$[6],.@a$[7],.@a$[8],.@a$[9],.@a$[10],.@a$[11],.@a$[12],.@a$[13],.@a$[14],.@a$[15],.@a$[16],.@a$[17],.@a$[18],.@a$[19]);
	// (Nota 1) Añadir más variables al menú si son necesarias.
	cleararray .@a$[0],0,getarraysize(.@a$);
	if(.@a == 1) goto Onf0;
	mes $@WE$;
	set .@a,$@WEm[.@a - 2];
	set .@b,getd("$@WE_2_"+.@a);
	if(Zeny < .@b) {
		mes "Lo siento.";
		mes "Para utilizar este servicio deberás pagar _880000"+.@b+" z_000000.";
		emotion 40;
		close;
	}
	if(.@a == 1) {
		getmapxy .@m$,.@x,.@y,0;
		set Zeny,Zeny - .@b;
                mes "Muy bien.";
		mes "A partir de ahora este lugar quedará guardado como tu Punto de Inicio.";
		save .@m$,.@x,.@y;
		specialeffect2 500;
		close2;
		emotion 12;
		end;
	}
	mes "Elige tu Destino.";
	next;
	while(getd("$@WE_1_"+.@a) == (-1)) {
		set .@c,0;
		cleararray .@a$[0],"",getarraysize(.@a$[0]);
		while(.@c < getarraysize(getd("$@WE_4_"+.@a))) {
			set .@d,getd("$@WE_4_"+.@a+"["+.@c+"]");
			set .@e,getd("$@WE_1_"+.@d);
			if(!.@e || (getd("WE_"+(.@e / 31)) & pow(2,.@e % 31))) set .@b$,"000000";
			else if(.@e == (-1)) set .@b$,"444444";
			else set .@b$,"bbbbbb";
			set .@a$[.@c],"^"+.@b$+""+getd("$@WE_2_"+.@d+"$")+"^000000";
			set .@c,.@c + 1;
		}
		set .@g,getarraysize(.@f);
		set .@f[.@g],.@a;
		if(.@g) set .@c$,"Atrás";
		else set .@c$,"Salir";
		set .@c,select("^880000"+.@c$+"^000000",.@a$[0],.@a$[1],.@a$[2],.@a$[3],.@a$[4],.@a$[5],.@a$[6],.@a$[7],.@a$[8],.@a$[9],.@a$[10],.@a$[11],.@a$[12],.@a$[13],.@a$[14],.@a$[15],.@a$[16],.@a$[17],.@a$[18],.@a$[19],.@a$[20],.@a$[21],.@a$[22],.@a$[23],.@a$[24],.@a$[25],.@a$[26],.@a$[27],.@a$[28],.@a$[29],.@a$[30],.@a$[31],.@a$[32],.@a$[33],.@a$[34],.@a$[35],.@a$[36],.@a$[37],.@a$[38],.@a$[39],.@a$[40],.@a$[41],.@a$[42],.@a$[43],.@a$[44],.@a$[45],.@a$[46],.@a$[47],.@a$[48],.@a$[49]);
		// (Nota 2) Añadir más variables al menú si son necesarias.
		if(.@c == 1) {
			if(.@g) {
				set .@a,.@f[.@g - 1];
				cleararray .@f[.@g - 1],0,2;
			}
			else goto Onf0;
		}
		else {
			set .@c,.@c - 2;
			set .@a,getd("$@WE_4_"+.@a+"["+.@c+"]");
		}
	}
	mes $@WE$;
	if(compare(.@a$[.@c],"^bbbbbb")) {
		mes "Lo siento.";
		mes "Aún no has desbloqueado ese Destino.";
		emotion 40;
		close;
	}
	set Zeny,(Zeny - .@b);
	mes "Muy bien.";
	mes "Espera un segundo mientras te abro un portal...";
	close2;
	specialeffect2 71;
	pcblockmove getcharid(3),1;
	sleep2 500;
	specialeffect2 402;
	sleep2 500;
	emotion 12;
	specialeffect2 6;
	sleep2 200;
	specialeffect2 304;
	warp getd("$@WE_3_"+.@a+"$"),getd("$@WE_4_"+.@a),getd("$@WE_5_"+.@a);
	pcblockmove getcharid(3),0;
	end;

Onf0:
	mes $@WE$;
	mes "Hasta pronto.";
	emotion 12;
	close;
}

alberta,195,142,4	duplicate(WE)	WE#1	918
alberta,47,250,5	duplicate(WE)	WE#2	918
aldebaran,133,120,6	duplicate(WE)	WE#3	918
aldebaran,133,240,6	duplicate(WE)	WE#4	918
alde_gld,234,154,4	duplicate(WE)	WE#5	918
amatsu,244,283,6	duplicate(WE)	WE#6	918
amatsu,103,258,4	duplicate(WE)	WE#7	918
amatsu,207,104,4	duplicate(WE)	WE#8	918
ayothaya,212,208,4	duplicate(WE)	WE#9	918
ayothaya,157,82,4	duplicate(WE)	WE#10	918
comodo,180,333,4	duplicate(WE)	WE#11	918
comodo,205,116,4	duplicate(WE)	WE#12	918
comodo,320,179,4	duplicate(WE)	WE#13	918
comodo,32,219,6	duplicate(WE)	WE#14	918
einbech,67,96,6	duplicate(WE)	WE#15	918
einbech,131,249,6	duplicate(WE)	WE#16	918
einbech,38,201,8	duplicate(WE)	WE#17	918
einbroch,78,187,2	duplicate(WE)	WE#18	918
einbroch,153,317,6	duplicate(WE)	WE#19	918
einbroch,152,53,4	duplicate(WE)	WE#20	918
einbroch,245,239,2	duplicate(WE)	WE#21	918
geffen,123,73,4	duplicate(WE)	WE#22	918
geffen,41,111,6	duplicate(WE)	WE#23	918
geffen,124,181,4	duplicate(WE)	WE#24	918
geffen,167,123,6	duplicate(WE)	WE#25	918
gef_fild13,197,231,4	duplicate(WE)	WE#26	918
gonryun,152,114,6	duplicate(WE)	WE#27	918
gonryun,172,182,2	duplicate(WE)	WE#28	918
gonryun,157,18,6	duplicate(WE)	WE#29	918
hugel,101,134,4	duplicate(WE)	WE#30	918
hugel,176,174,4	duplicate(WE)	WE#31	918
izlude,121,98,6	duplicate(WE)	WE#32	918
yuno,175,93,4	duplicate(WE)	WE#33	918
yuno,64,207,4	duplicate(WE)	WE#34	918
sch_gld,291,127,4	duplicate(WE)	WE#35	918
lighthalzen,209,99,6	duplicate(WE)	WE#36	918
lighthalzen,218,326,4	duplicate(WE)	WE#37	918
lighthalzen,311,303,4	duplicate(WE)	WE#38	918
louyang,207,104,6	duplicate(WE)	WE#39	918
louyang,67,219,4	duplicate(WE)	WE#40	918
xmas,139,310,6	duplicate(WE)	WE#41	918
xmas,157,110,4	duplicate(WE)	WE#42	918
morocc,166,80,4	duplicate(WE)	WE#43	918
morocc,43,174,4	duplicate(WE)	WE#44	918
morocc,166,293,4	duplicate(WE)	WE#45	918
morocc,275,197,8	duplicate(WE)	WE#46	918
morocc,33,294,4	duplicate(WE)	WE#47	918
moscovia,238,194,4	duplicate(WE)	WE#48	918
moscovia,157,64,4	duplicate(WE)	WE#49	918
niflheim,25,156,6	duplicate(WE)	WE#50	918
niflheim,201,184,4	duplicate(WE)	WE#51	918
payon,213,76,6	duplicate(WE)	WE#52	918
payon,164,49,2	duplicate(WE)	WE#53	918
payon,232,320,4	duplicate(WE)	WE#54	918
payon,63,124,6	duplicate(WE)	WE#55	918
pay_gld,201,161,4	duplicate(WE)	WE#56	918
prontera,165,75,4	duplicate(WE)	WE#57	918
prontera,36,212,6	duplicate(WE)	WE#58	918
prontera,164,174,4	duplicate(WE)	WE#59	918
prontera,263,213,4	duplicate(WE)	WE#60	918
prontera,161,316,4	duplicate(WE)	WE#61	918
prt_gld,166,79,4	duplicate(WE)	WE#62	918
rachel,260,136,4	duplicate(WE)	WE#63	918
rachel,150,140,4	duplicate(WE)	WE#64	918
rachel,135,49,4	duplicate(WE)	WE#65	918
rachel,35,131,6	duplicate(WE)	WE#66	918
aru_gld,179,330,6	duplicate(WE)	WE#67	918
umbala,117,130,8	duplicate(WE)	WE#68	918
umbala,163,253,4	duplicate(WE)	WE#69	918
veins,205,236,4	duplicate(WE)	WE#70	918
veins,222,356,4	duplicate(WE)	WE#71	918
veins,153,62,6	duplicate(WE)	WE#72	918
mid_camp,215,287,4	duplicate(WE)	WE#73	918
mid_camp,134,233,6	duplicate(WE)	WE#74	918
mid_camp,256,230,8	duplicate(WE)	WE#75	918
hu_fild05,190,211,5	duplicate(WE)	WE#76	918
ama_dun01,233,14,4	duplicate(WE)	WE#77	918
moc_fild04,208,329,4	duplicate(WE)	WE#78	918
moc_fild15,248,251,6	duplicate(WE)	WE#79	918
ayo_fild02,279,153,4	duplicate(WE)	WE#80	918
izlu2dun,103,96,6	duplicate(WE)	WE#81	918
mjolnir_02,84,360,4	duplicate(WE)	WE#82	918
nameless_n,158,179,8	duplicate(WE)	WE#83	918
gef_dun00,107,99,4	duplicate(WE)	WE#84	918
glast_01,371,295,2	duplicate(WE)	WE#85	918
glast_01,191,120,6	duplicate(WE)	WE#86	918
glast_01,65,110,6	duplicate(WE)	WE#87	918
glast_01,195,292,6	duplicate(WE)	WE#88	918
glast_01,65,197,8	duplicate(WE)	WE#89	918
prt_fild01,140,366,4	duplicate(WE)	WE#90	918
mjolnir_12,48,20,2	duplicate(WE)	WE#91	918
ra_temple,122,178,4	duplicate(WE)	WE#92	918
ra_fild01,237,332,4	duplicate(WE)	WE#93	918
jupe_cave,47,55,6	duplicate(WE)	WE#94	918
yuno_fild03,34,135,8	duplicate(WE)	WE#95	918
yuno_fild08,68,181,6	duplicate(WE)	WE#96	918
mosk_fild02,194,252,4	duplicate(WE)	WE#97	918
odin_tem01,117,148,4	duplicate(WE)	WE#98	918
gef_fild10,61,334,6	duplicate(WE)	WE#99	918
prt_fild10,219,199,6	duplicate(WE)	WE#100	918
pay_arche,37,127,8	duplicate(WE)	WE#101	918
prt_fild05,266,207,6	duplicate(WE)	WE#102	918
moc_ruins,55,157,6	duplicate(WE)	WE#103	918
moc_fild19,106,101,5	duplicate(WE)	WE#104	918
alb2trea,74,101,6	duplicate(WE)	WE#105	918
tha_scene01,139,194,2	duplicate(WE)	WE#106	918
ve_fild03,172,238,4	duplicate(WE)	WE#107	918
tur_dun01,147,54,6	duplicate(WE)	WE#108	918
// El nombre de los NPCs debe continuar el modelo dado.